Hi Branden,
On Sat, Aug 31, 2024 at 09:59:12PM GMT, G. Branden Robinson wrote:
> Hi Alex,
>
> At 2024-09-01T00:30:26+0200, Alejandro Colomar wrote:
> > Using indentation for the scripts (and cat(1) before a script starts)
> > would probably help.
>
> Ok, I'll do that in my next submission.
>
> > > > Could you split this change into some simpler smaller patches?
> > >
> > > That's harder. It's a scripted change. I don't think breaking it
> > > up by individual sed commands is going to enlighten anyone. But it
> > > would be easy to break it up by affected file...
> >
> > Do the individual sed(1) commands produce good states? Or are they
> > temporary steps that would not be good by themselves?
>
> How about this? How about I improve the internal documentation of each
> sed script so that it discloses the sorts of case to which each
> substitution applies?
While that would help, I still think that each case should be handled in
a different commit.
Have a lovely day!
Alex
>
> $ cat fix-man-page-refs-in-tbl-tables-1.sed
> # Rewrite man page cross references inside tbl(1) text blocks to use
> # man(7) macros instead of troff(1) font selection escape sequences.
> /^\.\\"/b
> # Case: (handled in commit 9d21f97766, 2024-07-27)
> # T{
> # See \fBchown\fP(2) for
> # T}
> /T{$/,/^T}/s/ \\fB\([^\\]*\)\\fP\(([0-9][a-z]*)\) /\
> .BR \1 \2\\"1A\
> /
> # Case:
> # T{
> # the map that is loaded by the utility \fBmapscrn\fP(8).
> # T}
> /T{$/,/^T}/s/ \\fB\([^\\]*\)\\fP\(([0-9][a-z]*)\)\([^0-9a-z]\+\)$/\
> .BR \1 \2\3\\"1B/
> # Case:
> # T{
> # by \fBxterm\fP(1)'s \fBhpLowerleftBugCompat\fP resource).
> # T}
> /T{$/,/^T}/s/ \\fB\([^\\]*\)\\fP\(([0-9][a-z]*)\)\([^ ]\+\) \(.*\)/\
> .BR \1 \2\3\\"1C\
> \4/
>
> I'll be taking out the injected "1A", "1B", "1C" comments before
> submitting. But they were helpful in development.
>
> Regards,
> Branden
--
<https://www.alejandro-colomar.es/>
Attachment:
signature.asc
Description: PGP signature
