a macro to detect wether \ escapes in fortran

[Patrice Dumas <pertusus@xxxxxxx>]

Hi,

In the attached file there is a macro which could be used to test if a 
backslash escapes characters, the test being the escape of '.

Pat

# _AC_PROG_FC_BACKSLASH_ESCAPE
# ---------------------------------
#
# Find if a backslash `\' escapes in quoted strings.

AC_DEFUN([_AC_PROG_FC_BACKSLASH_ESCAPE],
[_AC_FORTRAN_ASSERT()dnl
AC_CACHE_CHECK([whether backslash escapes], 
  [ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape],
[AC_COMPILE_IFELSE([AC_LANG_SOURCE([[      program backslash
      character string*3

      string='\' '
      end
]])],
[ AS_TR_SH(ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape)='yes' ],
[ AS_TR_SH(ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape)='no' ])])

if test "z$AS_TR_SH(ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape)" = "zyes"; then
   AC_DEFINE_UNQUOTED(AS_TR_CPP([]_AC_FC[]_backslash_escape), 
     $AS_TR_SH(ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape),
     [Define to 1 if a backslash escapes in strings.])
fi

AS_TR_SH([]_AC_FC[]_BACKSLASH_ESCAPE)=$AS_TR_SH(ac_cv_[]_AC_LANG_ABBREV[]_backslash_escape)
])

# AC_PROG_F77_BACKSLASH_ESCAPE
# --------------------------------
AC_DEFUN([AC_PROG_F77_BACKSLASH_ESCAPE],
[AC_REQUIRE([AC_PROG_F77])dnl
AC_LANG_PUSH(Fortran 77)dnl
_AC_PROG_FC_BACKSLASH_ESCAPE
AC_LANG_POP(Fortran 77)dnl
])# AC_PROG_F77_BACKSLASH_ESCAPE


# AC_PROG_FC_BACKSLASH_ESCAPE
# --------------------------------
AC_DEFUN([AC_PROG_FC_BACKSLASH_ESCAPE],
[AC_REQUIRE([AC_PROG_FC])dnl
AC_LANG_PUSH(Fortran)dnl
_AC_PROG_FC_BACKSLASH_ESCAPE
AC_LANG_POP(Fortran)dnl
])# AC_PROG_FC_BACKSLASH_ESCAPE



_______________________________________________
Autoconf mailing list
Autoconf@xxxxxxx
http://lists.gnu.org/mailman/listinfo/autoconf