Arguments are supposed to be quoted in square brackets. Fix several that
weren't.
Sort and reformat the `AC_OUTPUT_FILES` argument list while we're at it.
Signed-off-by: Jeremy Sowden <jeremy@xxxxxxxxxx>
---
configure.ac | 94 ++++++++++++++++++++++++++++++++++------------------
1 file changed, 61 insertions(+), 33 deletions(-)
diff --git a/configure.ac b/configure.ac
index 154650000fb1..1e321e6ff0a5 100644
--- a/configure.ac
+++ b/configure.ac
@@ -21,7 +21,7 @@ AC_SEARCH_LIBS([dlopen], [dl], [libdl_LIBS="$LIBS"; LIBS=""])
dnl Checks for header files.
AC_HEADER_DIRENT
-AC_CHECK_HEADERS(fcntl.h unistd.h)
+AC_CHECK_HEADERS([fcntl.h unistd.h])
dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
@@ -31,12 +31,14 @@ AC_SYS_LARGEFILE
dnl Checks for library functions.
AC_FUNC_VPRINTF
-AC_CHECK_FUNCS(socket strerror)
+AC_CHECK_FUNCS([socket strerror])
AC_SEARCH_LIBS([pthread_create], [pthread], [libpthread_LIBS="$LIBS"; LIBS=""])
-AC_ARG_ENABLE(ulog,
- AS_HELP_STRING([--enable-ulog], [Enable ulog module [default=yes]]),[enable_ulog=$enableval],[enable_ulog=yes])
+AC_ARG_ENABLE([ulog],
+ [AS_HELP_STRING([--enable-ulog], [Enable ulog module [default=yes]])],
+ [enable_ulog=$enableval],
+ [enable_ulog=yes])
AM_CONDITIONAL([BUILD_ULOG], [test "x$enable_ulog" = "xyes"])
if [! test "x$enable_ulog" = "xyes"]; then
enable_ulog="no"
@@ -44,8 +46,11 @@ fi
dnl Check for the right nfnetlink version
PKG_CHECK_MODULES([LIBNFNETLINK], [libnfnetlink >= 1.0.1])
-AC_ARG_ENABLE(nflog,
- AS_HELP_STRING([--enable-nflog], [Enable nflog module [default=yes]]),[enable_nflog=$enableval],[enable_nflog=yes])
+
+AC_ARG_ENABLE([nflog],
+ [AS_HELP_STRING([--enable-nflog], [Enable nflog module [default=yes]])],
+ [enable_nflog=$enableval],
+ [enable_nflog=yes])
AS_IF([test "x$enable_nflog" = "xyes"], [
PKG_CHECK_MODULES([LIBNETFILTER_LOG], [libnetfilter_log >= 1.0.0])
AC_DEFINE([BUILD_NFLOG], [1], [Building nflog module])
@@ -55,8 +60,10 @@ if [! test "x$enable_nflog" = "xyes"]; then
enable_nflog="no"
fi
-AC_ARG_ENABLE(nfct,
- AS_HELP_STRING([--enable-nfct], [Enable nfct module [default=yes]]),[enable_nfct=$enableval],[enable_nfct=yes])
+AC_ARG_ENABLE([nfct],
+ [AS_HELP_STRING([--enable-nfct], [Enable nfct module [default=yes]])],
+ [enable_nfct=$enableval],
+ [enable_nfct=yes])
AS_IF([test "x$enable_nfct" = "xyes"], [
PKG_CHECK_MODULES([LIBNETFILTER_CONNTRACK], [libnetfilter_conntrack >= 1.0.2])
AC_DEFINE([BUILD_NFCT], [1], [Building nfct module])
@@ -66,8 +73,10 @@ if [! test "x$enable_nfct" = "xyes"]; then
enable_nfct="no"
fi
-AC_ARG_ENABLE(nfacct,
- AS_HELP_STRING([--enable-nfacct], [Enable nfacct module [default=yes]]),[enable_nfacct=$enableval],[enable_nfacct=yes])
+AC_ARG_ENABLE([nfacct],
+ [AS_HELP_STRING([--enable-nfacct], [Enable nfacct module [default=yes]])],
+ [enable_nfacct=$enableval],
+ [enable_nfacct=yes])
AS_IF([test "x$enable_nfacct" = "xyes"], [
PKG_CHECK_MODULES([LIBMNL], [libmnl >= 1.0.3])
PKG_CHECK_MODULES([LIBNETFILTER_ACCT], [libnetfilter_acct >= 1.0.1])
@@ -78,22 +87,24 @@ if [! test "x$enable_nfacct" = "xyes"]; then
enable_nfacct="no"
fi
-AC_ARG_WITH([pgsql], AS_HELP_STRING([--without-pgsql], [Build without postgresql output plugin [default=test]]))
+AC_ARG_WITH([pgsql],
+ [AS_HELP_STRING([--without-pgsql], [Build without postgresql output plugin [default=test]])])
AS_IF([test "x$with_pgsql" != "xno"], [
CT_CHECK_POSTGRES_DB()
])
-AM_CONDITIONAL(HAVE_PGSQL, test "x$PQLIBPATH" != "x")
+AM_CONDITIONAL([HAVE_PGSQL], [test "x$PQLIBPATH" != "x"])
if test "x$PQLIBPATH" != "x"; then
enable_pgsql="yes"
else
enable_pgsql="no"
fi
-AC_ARG_WITH([mysql], AS_HELP_STRING([--without-mysql], [Build without mysql output plugin [default=test]]))
+AC_ARG_WITH([mysql],
+ [AS_HELP_STRING([--without-mysql], [Build without mysql output plugin [default=test]])])
AS_IF([test "x$with_mysql" != "xno"], [
CT_CHECK_MYSQL_DB()
])
-AM_CONDITIONAL(HAVE_MYSQL, test "x$MYSQL_LIB" != "x")
+AM_CONDITIONAL([HAVE_MYSQL], [test "x$MYSQL_LIB" != "x"])
if test "x$MYSQL_LIB" != "x"; then
enable_mysql="yes"
else
@@ -101,7 +112,8 @@ else
fi
-AC_ARG_WITH([sqlite], AS_HELP_STRING([--without-sqlite], [Build without SQLITE3 output plugin [default=test]]))
+AC_ARG_WITH([sqlite],
+ [AS_HELP_STRING([--without-sqlite], [Build without SQLITE3 output plugin [default=test]])])
AS_IF([test "x$with_sqlite" != "xno"], [
PKG_CHECK_MODULES([libsqlite3], [sqlite3], [], [:])
])
@@ -112,18 +124,20 @@ else
enable_sqlite3="no"
fi
-AC_ARG_WITH([dbi], AS_HELP_STRING([--without-dbi], [Build without DBI output plugin [default=test]]))
+AC_ARG_WITH([dbi],
+ [AS_HELP_STRING([--without-dbi], [Build without DBI output plugin [default=test]])])
AS_IF([test "x$with_dbi" != "xno"], [
CT_CHECK_DBI()
])
-AM_CONDITIONAL(HAVE_DBI, test "x$DBI_LIB" != "x")
+AM_CONDITIONAL([HAVE_DBI], [test "x$DBI_LIB" != "x"])
if test "x$DBI_LIB" != "x"; then
enable_dbi="yes"
else
enable_dbi="no"
fi
-AC_ARG_WITH([pcap], AS_HELP_STRING([--without-pcap], [Build without PCAP output plugin [default=test]]))
+AC_ARG_WITH([pcap],
+ [AS_HELP_STRING([--without-pcap], [Build without PCAP output plugin [default=test]])])
AS_IF([test "x$with_pcap" != "xno"], [
AC_SEARCH_LIBS([pcap_close], [pcap], [libpcap_LIBS="-lpcap"; LIBS=""])
])
@@ -134,7 +148,8 @@ else
enable_pcap="no"
fi
-AC_ARG_WITH([jansson], AS_HELP_STRING([--without-jansson], [Build without JSON output plugin [default=test]]))
+AC_ARG_WITH([jansson],
+ [AS_HELP_STRING([--without-jansson], [Build without JSON output plugin [default=test]])])
AS_IF([test "x$with_jansson" != "xno"], [
PKG_CHECK_MODULES([libjansson], [jansson], [], [:])
])
@@ -146,20 +161,33 @@ else
fi
AC_ARG_WITH([ulogd2libdir],
- AS_HELP_STRING([--with-ulogd2libdir=PATH],
- [Default directory to load ulogd2 plugin from [[LIBDIR/ulogd]]]),
- [ulogd2libdir="$withval"],
- [ulogd2libdir="${libdir}/ulogd"])
-
-AC_CONFIG_FILES(include/Makefile include/ulogd/Makefile include/libipulog/Makefile \
- include/linux/Makefile include/linux/netfilter/Makefile \
- include/linux/netfilter_ipv4/Makefile libipulog/Makefile \
- input/Makefile input/packet/Makefile input/flow/Makefile \
- input/sum/Makefile \
- filter/Makefile filter/raw2packet/Makefile \
- output/Makefile output/pcap/Makefile output/mysql/Makefile output/pgsql/Makefile output/sqlite3/Makefile \
- output/dbi/Makefile output/ipfix/Makefile \
- src/Makefile Makefile)
+ [AS_HELP_STRING([--with-ulogd2libdir=PATH], [Default directory to load ulogd2 plugin from [[LIBDIR/ulogd]]])],
+ [ulogd2libdir="$withval"],
+ [ulogd2libdir="${libdir}/ulogd"])
+
+AC_CONFIG_FILES([Makefile
+ filter/Makefile
+ filter/raw2packet/Makefile
+ include/Makefile
+ include/libipulog/Makefile
+ include/linux/Makefile
+ include/linux/netfilter/Makefile
+ include/linux/netfilter_ipv4/Makefile
+ include/ulogd/Makefile
+ input/Makefile
+ input/flow/Makefile
+ input/packet/Makefile
+ input/sum/Makefile
+ libipulog/Makefile
+ output/Makefile
+ output/dbi/Makefile
+ output/ipfix/Makefile
+ output/mysql/Makefile
+ output/pcap/Makefile
+ output/pgsql/Makefile
+ output/sqlite3/Makefile
+ src/Makefile])
+
AC_OUTPUT
define([EXPAND_VARIABLE],
--
2.33.0
