Since SLOB was removed and since
commit 6c6c47b063b5 ("mm, slab: call kvfree_rcu_barrier() from kmem_cache_destroy()"),
it is not necessary to use call_rcu when the callback only performs
kmem_cache_free. Use kfree_rcu() directly.
The changes were done using the following Coccinelle semantic patch.
This semantic patch is designed to ignore cases where the callback
function is used in another way.
// <smpl>
#spatch --all-includes --include-headers
@r@
expression e;
local idexpression e2;
identifier cb,f,g;
position p;
@@
(
call_rcu(...,e2)
|
call_rcu(&e->f,cb@p)
|
call_rcu(&e->f.g,cb@p)
)
@r1@
type T,T1;
identifier x,r.cb;
@@
cb(...) {
(
kmem_cache_free(...);
|
T x = ...;
kmem_cache_free(...,(T1)x);
|
T x;
x = ...;
kmem_cache_free(...,(T1)x);
)
}
@s depends on r1@
position p != r.p;
identifier r.cb;
@@
cb@p
@script:ocaml@
cb << r.cb;
p << s.p;
@@
Printf.eprintf "Other use of %s at %s:%d\n" cb (List.hd p).file (List.hd p).line
@depends on r1 && !s@
expression e;
identifier r.cb,f,g;
position r.p;
@@
(
- call_rcu(&e->f,cb@p)
+ kfree_rcu(e,f)
|
- call_rcu(&e->f.g,cb@p)
+ kfree_rcu(e,f.g)
)
@r1a depends on !s@
type T,T1;
identifier x,r.cb;
@@
- cb(...) {
(
- kmem_cache_free(...);
|
- T x = ...;
- kmem_cache_free(...,(T1)x);
|
- T x;
- x = ...;
- kmem_cache_free(...,(T1)x);
)
- }
@r2 depends on !r1@
identifier r.cb;
@@
cb(...) {
...
}
@script:ocaml depends on !r1 && !r2@
cb << r.cb;
@@
Printf.eprintf "need definition for %s\n" cb
// </smpl>
---
arch/powerpc/kvm/book3s_mmu_hpte.c | 8 ------
block/blk-ioc.c | 9 ------
drivers/net/wireguard/allowedips.c | 9 +-----
fs/ecryptfs/dentry.c | 8 ------
fs/nfsd/nfs4state.c | 9 ------
kernel/time/posix-timers.c | 9 ------
net/batman-adv/translation-table.c | 47 ++----------------------------------
net/bridge/br_fdb.c | 9 ------
net/can/gw.c | 13 ++-------
net/ipv4/fib_trie.c | 8 ------
net/ipv4/inetpeer.c | 9 +-----
net/ipv6/ip6_fib.c | 9 ------
net/ipv6/xfrm6_tunnel.c | 8 ------
net/kcm/kcmsock.c | 10 -------
net/netfilter/nf_conncount.c | 10 -------
net/netfilter/nf_conntrack_expect.c | 10 -------
net/netfilter/xt_hashlimit.c | 9 ------
17 files changed, 23 insertions(+), 171 deletions(-)
