new tor version

[Florian Preinstorfer <nblock@xxxxxxxxxxxx>]

Hi,
The torproject released a new version of tor that fix some security problems. 
I updated the PKGBUILD, here is the patch:

Index: PKGBUILD
===================================================================
--- PKGBUILD    (Revision 64847)
+++ PKGBUILD    (Arbeitskopie)
@@ -3,7 +3,7 @@
 # Contributor: simo <simo@xxxxxxxxxxxxx>

 pkgname=tor
-pkgver=0.2.1.21
+pkgver=0.2.1.22
 pkgrel=1
 pkgdesc="Anonymizing overlay network"
 arch=('i686' 'x86_64')
@@ -15,7 +15,7 @@
 source=(http://www.torproject.org/dist/tor-${pkgver}.tar.gz
        'tor.conf'
        'tor.rc')
-md5sums=('54f7a801d824cd9c13ce672d483926d6'
+md5sums=('583501a989ed0c39e209b604c3671ecd'
          '56c75d4e8a66f34167d31e38c43793dd'
          '23348b8e3b38c6ed2a45b4be42a7de8e')


full PKGBUILD:
# $Id: PKGBUILD 62137 2010-01-03 11:07:08Z andrea $
# Maintainer: 
# Contributor: simo <simo@xxxxxxxxxxxxx>

pkgname=tor
pkgver=0.2.1.22
pkgrel=1
pkgdesc="Anonymizing overlay network"
arch=('i686' 'x86_64')
url="http://www.torproject.org/";
license=('BSD')
depends=('openssl' 'libevent' 'tsocks' 'bash')
backup=('etc/tor/torrc' 'etc/tor/torrc-dist' 'etc/tor/tor-tsocks.conf')
install=tor.install
source=(http://www.torproject.org/dist/tor-${pkgver}.tar.gz
        'tor.conf'
        'tor.rc')
md5sums=('583501a989ed0c39e209b604c3671ecd'
         '56c75d4e8a66f34167d31e38c43793dd'
         '23348b8e3b38c6ed2a45b4be42a7de8e')

build() {
  cd ${srcdir}/${pkgname}-${pkgver}

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var || return 1
  make || return 1
  make DESTDIR="$pkgdir" install || return 1

  install -d ${pkgdir}/var/lib/tor || return 1

  mv "$pkgdir/etc/tor/torrc.sample" "$pkgdir/etc/tor/torrc-dist" || return 1
  install -D -m644 "$srcdir/tor.conf" "$pkgdir/etc/tor/torrc" || return 1
  install -D -m755 "$srcdir/tor.rc" "$pkgdir/etc/rc.d/tor" || return 1

  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/tor/LICENSE" || return 1
}

greetings,
-- 
nblock