PKGBUILD for updated libtorrent and rtorrent

[Partha Chowdhury <kira.laucas@xxxxxxxxx>]

Following the discussions here,
http://www.archlinux.org/pipermail/arch-general/2009-August/006881.html

i have attached modified PKGBUILDs for libtorrent and rtorrent for updated
versions 0.12.5 and 0.8.5 repectively.

# $Id: PKGBUILD 82 2009-07-17 19:56:55Z aaron $
# Maintainer: Jeff Mickey <jeff@xxxxxxxxxxxxx>
# Contributor: sh__
# Contributor: Partha Chowdhury <parthachowdhury10@xxxxxxxxx>

pkgname=libtorrent
pkgver=0.12.5
pkgrel=1
pkgdesc="BitTorrent library written in C++"
arch=('i686' )
url="http://libtorrent.rakshasa.no";
license=('GPL')
depends=('libsigc++2.0' 'openssl')
options=('!libtool')
source=(http://libtorrent.rakshasa.no/downloads/$pkgname-$pkgver.tar.gz )
md5sums=('fe8155d364b220713074423100d4bf29')

build() {
  cd "$srcdir/$pkgname-$pkgver"
  CXXFLAGS="$CXXFLAGS -fno-strict-aliasing" \
    ./configure --prefix=/usr --disable-debug || return 1
  make || return 1
  make DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et:

# $Id: PKGBUILD 82 2009-07-17 19:56:55Z aaron $
# Maintainer: Jeff Mickey <jeff@xxxxxxxxxxxxx>
# Contributor: sh__
# Contributor: Partha chowdhury <parthachowdhury10@xxxxxxxxx>

pkgname=rtorrent
pkgver=0.8.5
pkgrel=1
pkgdesc="Ncurses BitTorrent client based on libTorrent"
arch=('i686' )
url="http://libtorrent.rakshasa.no";
license=('GPL')
depends=('libtorrent>=0.12.5' 'curl>=7.19.5' 'xmlrpc-c')
source=(http://libtorrent.rakshasa.no/downloads/$pkgname-$pkgver.tar.gz )
install=$pkgname.install
md5sums=('e701095e1824b7e512a17000f4c0a783')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  CXXFLAGS="$CXXFLAGS -fno-strict-aliasing" \
    ./configure --prefix=/usr --disable-debug --with-xmlrpc-c || return 1
  make || return 1
  make DESTDIR="$pkgdir" install
}


# vim:set ts=2 sw=2 et: