What might induce configure to insert a space after "-g" and before "gdb3"?
configure:15849: result: no
configure:15864: checking whether uname(2) is POSIX
configure:15880: /usr/bin/gcc -std=gnu99 -o conftest -ggdb3 conftest.c -ldl >&5
+ eval '$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS >&5'
++ /usr/bin/gcc -std=gnu99 -o conftest -ggdb3 conftest.c -ldl
configure:15880: $? = 0
configure:15880: ./conftest
+ eval './conftest$ac_exeext'
++ ./conftest
configure:15880: $? = 0
configure:15892: result: yes
configure:15905: checking whether runtime library dirs can be specified
configure:15927: result: -Wl,-R${libdir}
configure:16070: checking whether a reg expr header is specified
configure:16077: result: no
configure:16103: checking whether with-libregex was specified
configure:16110: result: no
configure:16129: checking whether with-libregex-cflags was specified
configure:16136: result: no
configure:16147: checking whether with-libregex-libs was specified
configure:16154: result: no
configure:16191: checking whether libregex functions properly
configure:16223: /usr/bin/gcc -std=gnu99 -o conftest -g gdb3 conftest.c -ldl >&5
+ eval '$CC -o conftest$ac_exeext $CFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS >&5'
++ /usr/bin/gcc -std=gnu99 -o conftest -g gdb3 conftest.c -ldl
gcc: error: gdb3: No such file or directory
configure:16223: $? = 1
configure: program exited with status 1
Below is the horrid monster macro that fires off the failing compilation.
Since I pulled a new automake today and since this is a configure problem,
I'm sending to both. Thank you for any info at all!
AC_DEFUN([LIBOPTS_WITHLIB_REGEX],[
AC_ARG_WITH([libregex],
AS_HELP_STRING([--with-libregex], [libregex installation prefix]),
[libopts_cv_with_libregex_root=${with_libregex}],
AC_CACHE_CHECK([whether with-libregex was specified], libopts_cv_with_libregex_root,
libopts_cv_with_libregex_root=no)
) # end of AC_ARG_WITH libregex
if test "${with_libregex+set}" = set && \
test "X${withval}" = Xno
then ## disabled by request
libopts_cv_with_libregex_root=no
libopts_cv_with_libregex_cflags=no
libopts_cv_with_libregex_libs=no
else
AC_ARG_WITH([libregex-cflags],
AS_HELP_STRING([--with-libregex-cflags], [libregex compile flags]),
[libopts_cv_with_libregex_cflags=${with_libregex_cflags}],
AC_CACHE_CHECK([whether with-libregex-cflags was specified], libopts_cv_with_libregex_cflags,
libopts_cv_with_libregex_cflags=no)
) # end of AC_ARG_WITH libregex-cflags
AC_ARG_WITH([libregex-libs],
AS_HELP_STRING([--with-libregex-libs], [libregex link command arguments]),
[libopts_cv_with_libregex_libs=${with_libregex_libs}],
AC_CACHE_CHECK([whether with-libregex-libs was specified], libopts_cv_with_libregex_libs,
libopts_cv_with_libregex_libs=no)
) # end of AC_ARG_WITH libregex-libs
case "X${libopts_cv_with_libregex_cflags}" in
Xyes|Xno|X )
case "X${libopts_cv_with_libregex_root}" in
Xyes|Xno|X ) libopts_cv_with_libregex_cflags=no ;;
* ) libopts_cv_with_libregex_cflags=-I${libopts_cv_with_libregex_root}/include ;;
esac
esac
case "X${libopts_cv_with_libregex_libs}" in
Xyes|Xno|X )
case "X${libopts_cv_with_libregex_root}" in
Xyes|Xno|X ) libopts_cv_with_libregex_libs=no ;;
* ) libopts_cv_with_libregex_libs="-L${libopts_cv_with_libregex_root}/lib -lregex";;
esac
esac
libopts_save_CPPFLAGS="${CPPFLAGS}"
libopts_save_LIBS="${LIBS}"
fi ## disabled by request
case "X${libopts_cv_with_libregex_cflags}" in
Xyes|Xno|X )
libopts_cv_with_libregex_cflags="" ;;
* ) CPPFLAGS="${CPPFLAGS} ${libopts_cv_with_libregex_cflags}" ;;
esac
case "X${libopts_cv_with_libregex_libs}" in
Xyes|Xno|X )
libopts_cv_with_libregex_libs="" ;;
* )
LIBS="${LIBS} ${libopts_cv_with_libregex_libs}" ;;
esac
LIBREGEX_CFLAGS=""
LIBREGEX_LIBS=""
AC_MSG_CHECKING([whether libregex functions properly])
AC_CACHE_VAL([libopts_cv_with_libregex],[
AC_RUN_IFELSE([@%:@include <stdio.h>
@%:@include <stdlib.h>
@%:@include <sys/types.h>
@%:@include REGEX_HEADER
static regex_t re;
void comp_re( char const* pzPat ) {
int res = regcomp( &re, pzPat, REG_EXTENDED|REG_ICASE|REG_NEWLINE );
if (res == 0) return;
exit( res ); }
int main() {
regmatch_t m@<:@2@:>@;
comp_re( "^.*\@S|@" );
comp_re( "()|no.*" );
comp_re( "." );
if (regexec( &re, "X", 2, m, 0 ) != 0) return 1;
if ((m@<:@0@:>@.rm_so != 0) || (m@<:@0@:>@.rm_eo != 1)) {
fputs( "error: regex -->.<-- did not match\n", stderr );
return 1;
}
return 0; }],
[libopts_cv_with_libregex=yes], [libopts_cv_with_libregex=no],
[libopts_cv_with_libregex=no]) # end of AC_RUN_IFELSE
]) # end of AC_CACHE_VAL for libopts_cv_with_libregex
AC_MSG_RESULT([${libopts_cv_with_libregex}])
if test "X${libopts_cv_with_libregex}" != Xno
then
AC_DEFINE([WITH_LIBREGEX],[1],
[Define this if a working libregex can be found])
else
CPPFLAGS="${libopts_save_CPPFLAGS}"
LIBS="${libopts_save_LIBS}"
fi
]) # end of AC_DEFUN of LIBOPTS_WITHLIB_REGEX
_______________________________________________
Autoconf mailing list
Autoconf@xxxxxxx
https://lists.gnu.org/mailman/listinfo/autoconf
