This patch only adds --with-storage-vstorage build option.
In order to use vstorage as a backend for storage pool
vstorage tools should be installed.
Signed-off-by: Olga Krishtal <okrishtal@xxxxxxxxxxxxx>
---
configure.ac | 4 +++
m4/virt-storage-vstorage.m4 | 73 +++++++++++++++++++++++++++++++++++++++++++++
2 files changed, 77 insertions(+)
create mode 100644 m4/virt-storage-vstorage.m4
diff --git a/configure.ac b/configure.ac
index c67ba79..2cc378d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -570,6 +570,7 @@ LIBVIRT_STORAGE_ARG_RBD
LIBVIRT_STORAGE_ARG_SHEEPDOG
LIBVIRT_STORAGE_ARG_GLUSTER
LIBVIRT_STORAGE_ARG_ZFS
+LIBVIRT_STORAGE_ARG_VSTORAGE
if test "$with_libvirtd" = "no"; then
with_storage_dir=no
@@ -583,6 +584,7 @@ if test "$with_libvirtd" = "no"; then
with_storage_sheepdog=no
with_storage_gluster=no
with_storage_zfs=no
+ with_storage_vstorage=no
fi
dnl storage-fs does not work on MacOS X
@@ -602,6 +604,7 @@ LIBVIRT_STORAGE_CHECK_RBD
LIBVIRT_STORAGE_CHECK_SHEEPDOG
LIBVIRT_STORAGE_CHECK_GLUSTER
LIBVIRT_STORAGE_CHECK_ZFS
+LIBVIRT_STORAGE_CHECK_VSTORAGE
if test "$with_storage_fs" = "yes" ||
test "$with_storage_gluster" = "yes"; then
@@ -944,6 +947,7 @@ LIBVIRT_STORAGE_RESULT_RBD
LIBVIRT_STORAGE_RESULT_SHEEPDOG
LIBVIRT_STORAGE_RESULT_GLUSTER
LIBVIRT_STORAGE_RESULT_ZFS
+LIBVIRT_STORAGE_RESULT_VSTORAGE
AC_MSG_NOTICE([])
AC_MSG_NOTICE([Security Drivers])
AC_MSG_NOTICE([])
diff --git a/m4/virt-storage-vstorage.m4 b/m4/virt-storage-vstorage.m4
new file mode 100644
index 0000000..8a926c8
--- /dev/null
+++ b/m4/virt-storage-vstorage.m4
@@ -0,0 +1,73 @@
+dnl The storage vstorage check
+dnl
+dnl Copyright (C) 2016 Parallels IP Holdings GmbH, Inc.
+dnl
+dnl This library is free software; you can redistribute it and/or
+dnl modify it under the terms of the GNU Lesser General Public
+dnl License as published by the Free Software Foundation; either
+dnl version 2.1 of the License, or (at your option) any later version.
+dnl
+dnl This library is distributed in the hope that it will be useful,
+dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+dnl Lesser General Public License for more details.
+dnl
+dnl You should have received a copy of the GNU Lesser General Public
+dnl License along with this library. If not, see
+dnl <http://www.gnu.org/licenses/>.
+dnl
+
+
+AC_DEFUN([LIBVIRT_STORAGE_ARG_VSTORAGE], [
+ LIBVIRT_ARG_WITH_FEATURE([STORAGE_VSTORAGE],
+ [Virtuozzo Storage backend for the storage driver],
+ [check])
+])
+
+AC_DEFUN([LIBVIRT_STORAGE_CHECK_VSTORAGE], [
+ if test "$with_storage_vstorage" = "yes" ||
+ test "$with_storage_vstorage" = "check"; then
+ AC_PATH_PROG([VSTORAGE], [vstorage], [], [$LIBVIRT_SBIN_PATH])
+ AC_PATH_PROG([VSTORAGE_MOUNT], [vstorage-mount], [], [$LIBVIRT_SBIN_PATH])
+ AC_PATH_PROG([UMOUNT], [umount], [], [$LIBVIRT_SBIN_PATH])
+
+ if test "$with_storage_vstorage" = "yes"; then
+ if test -z "$VSTORAGE" || test -z "$VSTORAGE_MOUNT"; then
+ AC_MSG_ERROR([We need vstorage and vstorage-mount tool for Vstorage storage driver]);
+ fi
+ if test -z "$UMOUNT" ; then
+ AC_MSG_ERROR([We need umount for Vstorage storage driver]);
+ fi
+ else
+ if test -z "$VSTORAGE" ; then
+ with_storage_vstorage=no
+ fi
+ if test -z "$VSTORAGE_MOUNT" ; then
+ with_storage_vstorage=no
+ fi
+ if test -z "$UMOUNT" ; then
+ with_storage_vstorage=no
+ fi
+
+ if test "$with_storage_fs" = "check" ; then
+ with_storage_vstorage=yes
+ fi
+ fi
+
+ if test "$with_storage_vstorage" = "yes" ; then
+ AC_DEFINE_UNQUOTED([WITH_STORAGE_VSTORAGE], 1,
+ [whether Vstorage backend for storage driver is enabled])
+ AC_DEFINE_UNQUOTED([VSTORAGE], ["$VSTORAGE"],
+ [Location or name of the vstorage client tool])
+ AC_DEFINE_UNQUOTED([VSTORAGE_MOUNT], ["$VSTORAGE_MOUNT"],
+ [Location or name of the vstorage mount tool])
+ AC_DEFINE_UNQUOTED([UMOUNT], ["$UMOUNT"],
+ [Location or name of the umount programm])
+ fi
+ fi
+ AM_CONDITIONAL([WITH_STORAGE_VSTORAGE], [test "$with_storage_vstorage" = "yes"])
+])
+
+AC_DEFUN([LIBVIRT_STORAGE_RESULT_VSTORAGE], [
+ LIBVIRT_RESULT([Virtuozzo storage], [$with_storage_vstorage])
+])
--
1.8.3.1
--
libvir-list mailing list
libvir-list@xxxxxxxxxx
https://www.redhat.com/mailman/listinfo/libvir-list
