Re: Dealing with rpmsave files

[Jason L Tibbitts III <tibbs@xxxxxxxxxxx>]

>>>>> "SPK" == Sean P Kane <spkane@xxxxxxxxxxxxxx> writes:

SPK> Is there a way to make rpm overwrite config files, since this is
SPK> before anyone has edited themselves? Or has anyone come up with a
SPK> clever way of cleaning this up?

Not exactly what you were looking for, but here is the script I use to
detect config files that either were overwritten or need to have
changes merged in.  -q runs quietly; the exit code indicates whether
or not changes need to be looked at.  -d produces diffs.  The idea was
stolen from a very useful feature of IRIX.

 - J<

#!/usr/bin/perl
use Getopt::Std;
getopts('dq');

$| = 1;
@DIFF = qw(/usr/bin/diff -u);
@LS   = qw(/bin/ls -l);

@configfiles = `rpm -qac`;

for $i (@configfiles) {
  chomp $i;
  $old = -f "$i.rpmsave";
  $new = -f "$i.rpmnew";
  if ($old || $new) {

    # If running quietly, we can just exit the first time we see a difference
    if ($opt_q) {
      exit 1;
    }

    $package = `rpm -qf $i`;
    chomp $package;

    push @{$updates{$package}}, {file => $i,
				 old  => $old,
				 new  => $new,
				};
  }
}

exit 0 unless %updates;

for $package (sort keys %updates) {
  print "Updated files in package $package:\n";

  for $i (@{$updates{$package}}) {
    if ($i->{old}) {
      show ($i->{file}, "$i->{file}.rpmsave");
    }
    if ($i->{new}) {
      show ($i->{file}, "$i->{file}.rpmnew");
    }
  }
  print "\n";
}

exit 1;

sub show {
  my($old, $new) = @_;

  print "    " if $opt_d;
  system(@LS, $old);
  print "    " if $opt_d;
  system(@LS, $new);

  if ($opt_d) {
    print "Differences:\n", "="x40, "\n";
    system(@DIFF, $old, $new);
    print "="x40, "\n";
  }
}